todo/build.gradle.kts

import org.gradle.internal.os.OperatingSystem

plugins {
    val kotlinVersion = "2.2.0"
    kotlin("multiplatform") version kotlinVersion
    kotlin("plugin.serialization") version kotlinVersion
    id("org.sirekanyan.version-checker") version "1.0.14"
    distribution
}

group = "org.sirekanyan"
version = "1.0"

repositories {
    mavenCentral()
}

dependencies {
    commonMainImplementation("com.github.ajalt.clikt:clikt-core:5.0.3")
    commonMainImplementation("org.jetbrains.kotlinx:kotlinx-datetime:0.7.1")
    commonMainImplementation("org.jetbrains.kotlinx:kotlinx-io-core:0.8.0")
}

kotlin {
    val os = OperatingSystem.current()
    when {
        os.isLinux -> linuxX64("linux")
        os.isMacOsX -> macosX64("macos")
        else -> error("Unsupported operating system: $os")
    }.binaries {
        executable(listOf(if (hasProperty("release")) RELEASE else DEBUG))
    }
}

distributions {
    main {
        contents {
            from("build/bin/linux/releaseExecutable/todo.kexe") {
                rename { it.removeSuffix(".kexe") }
            }
        }
    }
}

tasks {
    getByName<Tar>("distTar") {
        compression = Compression.GZIP
        archiveExtension = ".tar.gz"
    }
}