devtools/app/build.gradle

apply plugin: 'com.android.application'
apply plugin: 'org.jetbrains.kotlin.android'
apply plugin: 'org.sirekanyan.version-checker'

android {
    namespace 'org.sirekanyan.devtools'
    compileSdkVersion 33
    defaultConfig {
        applicationId "org.sirekanyan.devtools"
        minSdkVersion 17
        targetSdkVersion 33
        versionCode 1
        versionName "1.0"
    }
    buildTypes {
        debug {
            applicationIdSuffix ".debug"
        }
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt')
            signingConfig debug.signingConfig
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    kotlinOptions {
        jvmTarget = "1.8"
    }
}

dependencies {
    implementation "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
    implementation 'androidx.appcompat:appcompat:1.6.1'
}

afterEvaluate {
    def grantSystemPermissions = {
        exec {
            def adbExecutable = android.properties['adbExecutable']
            def defaultPackage = android.defaultConfig.applicationId
            def debugSuffix = android.buildTypes['debug'].applicationIdSuffix
            commandLine('./grant.sh', adbExecutable, defaultPackage + debugSuffix)
        }
    }
    assembleDebug.doLast { grantSystemPermissions() }
    installDebug.doLast { grantSystemPermissions() }
}